REPRESENTACIÓN GRÁFICA DE NÚMEROS COMPLEJOS

ReIm [z] descompone el número complejo z como una lista de dos elementos {Real, Imaginario}

ReIm[z]

Ejemplos:

ReIm[-3+4I]

ReIm[I]

ReIm[2]

ListPlot nos permite hacer una representación gráfica de los números complejos:

ListPlot[ReIm[{I,E,-1-2 I,Sqrt[-I]}],PlotStyle->PointSize[Large]]

Otra forma de representar gráficamente los números complejos:

ComplexListPlot[{-2-2 I,-1-I,0,1+I,2+2 I}, PlotStyle->PointSize[Large]]

En sus múltiples variedades:

ComplexListPlot[{RandomComplex[{0,1+I},100],RandomComplex[{-2-2 I,2+2 I},100]}]

data=Table[a t Exp[2 π I t],{a,2,4},{t,0,1,0.02}];
ComplexListPlot[data,PlotLegends->{"a=2","a=3","a=4"}]

Podemos representar gráficamente la parte real e imaginaria de un complejo como un valor de una  función de variable real:

ReImPlot[Sqrt[(x^2-1) (x^2-4)],{x,-3,3}]

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-4,4}]

ReImPlot[{ArcSin[x],ArcCos[x]},{x,-4,4},PlotLabels->"Expressions"]

Dada una lista de valores complejos {z1, z2, ...} se puede representar como una lista de pares {Re[z1], Im[z1]}:

ComplexListPlot[Sin[Range[40]+2I]]

ComplexListPlot[{Sin[Range[40]+2I],Cos[Range[40]+2I]}]

{ComplexListPlot[{0,1+I,2+2I,3+3I,4+20I,5+5I,20+6I}],
ComplexListPlot[{0,1+I,2+2I,3+3I,4+20I,5+5I,20+6I},PlotRange->All]}

Podemos especificar etiquetas:

ComplexListPlot[{1+I->"a",2+2I->"b",3+3I->"c",4+4I->"d",5+3I->"e",6+2I->"f",7+I->"g"}]
ComplexListPlot[{1+I,2+2 I,3+3 I,4+4 I,5+3 I,6+2 I,7+I}->{"a","b","c","d","e","f","g"}]

Se puede especificar la localización de las etiquetas:

ComplexListPlot[{1+I,2+2 I,3+3 I,4+4 I,5+3 I,6+2 I,7+I}->{"a","b","c","d","e","f","g"},LabelingFunction->Above]

Los valores numéricos se pueden asociar con coordenadas (x, y):

ComplexListPlot[<|"a"->2+I,"b"->3-I,"c"->5+2I,"d"->7,"e"->11+2I,"f"->13-3I|>]

ComplexListPlot[SparseArray[RandomComplex[{0,1+I},25]]]

{ComplexListPlot[{{1+I,Style[3+2I,Red],6+3I},{1+4I,3+5I,6+6I}},PlotStyle->PointSize[0.05]],
ComplexListPlot[{Style[{1+I,Style[3+2I,Red],6+3I},Green],{1+4I,3+5I,6+6I}},PlotStyle->PointSize[0.05]],
ComplexListPlot[Style[{Style[{1+I,Style[3+2I,Red],6+3I},Green],{1+4I,3+5I,6+6I}},Blue],PlotStyle->PointSize[0.05]]}

Se pueden calcular resultados de una ecuación y proceder a representar los resultados, etiquetando los valores de los complejos:

ComplexListPlot[z/.Solve[(z^6)==1,z],LabelingFunction->(DisplayForm[RowBox[{"(",#1[[1]],#1[[2]],")"}]]&)]

ComplexListPlot[z/.Solve[(z^12)==1,z],LabelingFunction->(Arg[#1[[1]]+I#[[2]]]&)]

Quiet@ComplexListPlot[z/.Solve[(z^50)==1,z],LabelingFunction->(Arg[#1[[1]]+I#[[2]]]&),ImageSize->500]

Incluímos leyendas:

ComplexListPlot[{
NestList[(0.9+0.1I)#&,1+I,30],NestList[(0.9+0.2I)#&,1+I,30]
},PlotLegends->{0.1,0.2}]

matrix=RandomComplex[{-1-I,1+I},{10,10}];
evals1=Eigenvalues[matrix];
evals2=Eigenvalues[((matrix+ConjugateTranspose[matrix])/2)];
ComplexListPlot[{evals1,Legended[evals2,"eigenvalues of the\nsymmetric matrix"]}]

Utilizando Placed podemos cambiar la leyenda de posición:

ComplexListPlot[{evals1,Legended[evals2,Placed["eigenvalues of the symmetric matrix",Below]]}]

Podemos utilizar diferentes estilos:

f=(((z^6)+(z^3)+1)/((z^10)-1024));
zeros=z/.Solve[f==0,z];
poles=z/.Solve[Denominator[f]==0,z];
ComplexListPlot[{zeros,poles}]

ComplexListPlot[{zeros,poles},PlotStyle->{Blue,Red}]

Como aplicaciones:

Manipulate[ComplexListPlot[Labeled[Exp[#],#]&/@Table[2Pi I k/n,{k,0,n-1}],Prolog->{Circle[]},ImageSize->Medium,PlotMarkers->{Automatic, Medium},PlotRange->{{-1.2,1.2},{-1.2,1.2}}],{{n,6},2,20,1}]

ComplexListPlot[z/.Solve[(z^2)+z + 1==0,z],LabelingFunction->(DisplayForm[RowBox[{"(",#1[[1]],#1[[2]],")"}]]&)]